HSPTV!掲示板

インターネットエクスプローラーをHSPの方から起動させたり、
終了させたりしようとしています。起動はexecを使うとして、
終了はどのようにしたらよいか分かりません。どなたか教えて
もらえませんか。

IEの起動や終了をするには、COMオブジェクトを使用すればできます。

	URL="http://www.yahoo.co.jp" //表示するサイト
	screen 0,640,480
	button gosub "起動",*exec_
	button gosub "終了",*exit
	stop
*exec_
	if exec0!0 :return //起動していれば処理しない
	exec0=1
	//IEオブジェクト作成
	newcom objIE, "InternetExplorer.Application"
	objIE("Silent")  = 1
	objIE("Visible") = 1
	objIE->"Navigate" URL //サイトを表示
	return
*exit
	if exec0!1 :return //起動していなければ処理しない
	exec0=0
	objIE->"Quit"
	delcom objIE //COMオブジェクト廃棄
	return

KENTAさんありがとうございました。示していただいたスクリプトで、
思っていた通りのことができました。ところが、スクリプトを理解し
ないままいじっているうちに、次のようなことになってしまいました。
すみませんが、対処の仕方を教えていただけませんか。
１、起動ボタンを押すと、ヤフーの画面と接続中の画面の２つが起動する。
２、終了ボタンを押すと、接続中の画面だけが終了し、ヤフーの画面は残る。
３、２の代わりに、接続中の画面を画面右上の×で終了させ、ヤフーの画面を
　　終了ボタンで終了させようとすると、エラー３０（無効な名前がパラメー
　　ターに指定してあります）がでる。
自分ではどうする事も出来ないので、助けていただけませんか。

>１、起動ボタンを押すと、ヤフーの画面と接続中の画面の２つが起動する。
newcom命令でオブジェクト型変数のobjIEを再び作成し直してしまうので、
もうひとつ作成されたIEが開いてしまうのです。

>２、終了ボタンを押すと、接続中の画面だけが終了し、ヤフーの画面は残る。
遠隔操作をしているだけなので終了するには、
HSPの方から終了の命令を送らなければ、終了できません。

	onexit *owari

を最初の行に追加して、

*owari
	gosub *exit //起動していれば、終了する
	end

を最後の行に追加してみてください。

>３、２の代わりに、接続中の画面を画面右上の×で終了させ、ヤフーの画面を
>　　終了ボタンで終了させようとすると、エラー３０（無効な名前がパラメー
>　　ターに指定してあります）がでる。
遠隔操作しているIEが終了している状態で終了の命令を送っても、
その命令は失敗してしまうのでエラーが出るのです。

すいません。
１と３の対処法を書いていませんでした。
>１、起動ボタンを押すと、ヤフーの画面と接続中の画面の２つが起動する。
objIEがCOMオブジェクト型変数かどうかで判断するならば
元のスクリプトに

	//IEオブジェクト作成
	newcom objIE, "InternetExplorer.Application"
	objIE("Silent")  = 1
	objIE("Visible") = 1
	objIE->"Navigate" URL //サイトを表示

を

	if vartype(objIE)!6 {
	//IEオブジェクト作成
	newcom objIE, "InternetExplorer.Application"
	objIE("Silent")  = 1
	objIE("Visible") = 1
	objIE->"Navigate" URL //サイトを表示
	}

に変更して

	delcom objIE //COMオブジェクト廃棄

の下に

	objIE=0 //変数を整数に戻す

を追加してみてください

>３、２の代わりに、接続中の画面を画面右上の×で終了させ、ヤフーの画面を
>　　終了ボタンで終了させようとすると、エラー３０（無効な名前がパラメー
>　　ターに指定してあります）がでる。
ここではAPIのFindWindowを使って、遠隔操作しているIEがあるかどうか判断して
確認したほうが早いようです。

	//１、２、３の問題をを修正したのスクリプト
	#uselib "user32"
	#cfunc FindWindow "FindWindowA" var,int
	
	IEClass="IEFrame"
	
	onexit *owari
	
	URL="http://www.yahoo.co.jp" //表示するサイト
	
	screen 0,640,480
	button gosub "起動",*exec_
	button gosub "終了",*exit
	stop
*exec_
	if vartype(objIE)!6 { //１の問題修正
	//IEオブジェクト作成
	newcom objIE, "InternetExplorer.Application"
	IEhwnd=FindWindow(IEClass,0) //起動したIEのハンドルを取得
	objIE("Silent")  = 1
	objIE("Visible") = 1
	objIE->"Navigate" URL //サイトを表示
	}
	return
*exit
	IEhwnds=FindWindow(IEClass,0)
	if vartype(objIE)=6 & IEhwnds=IEhwnd { //３の問題修正
	objIE->"Quit"
	}
	if vartype(objIE)=6 {
	delcom objIE //COMオブジェクト廃棄
	objIE=0 //変数を整数に戻す
	}
	return
*owari //２の問題修正
	gosub *exit //起動していれば、終了する
	end

KENTAさんのにちょっと付け足し版

#include "user32.as"
//↑ IsWindowを利用するため

	URL="http://www.yahoo.co.jp" //表示するサイト
	screen 0,640,480
	button gosub "IE起動",*exec_
	button gosub "IE終了",*exit
	onexit *owari
	stop
*exec_
	if exec0!0 :return //起動していれば処理しない
	exec0=1
	//IEオブジェクト作成
	newcom objIE, "InternetExplorer.Application"
	hwndIE = objIE("HWND")  //開いたIEのウインドウハンドルを記憶しておく
	objIE("Silent")  = 1
	objIE("Visible") = 1
	objIE->"Navigate" URL //サイトを表示
	return
*exit
	if exec0!1 :return //起動していなければ処理しない
	IsWindow hwndIE   //開いたIEのウインドウが、まだ存在してるか？
	if stat : objIE->"Quit"  //もし存在してればIEを終了させる
	delcom objIE //COMオブジェクト廃棄
	exec0=0
	return
*owari
	gosub *exit //起動していれば、終了する
	end

KENTAさん、aさん、お手数をおかけしまして、申し訳ありません。
ただ、KENTAさんの新しいスクリプトでは、接続中の真っ白な画面も
ヤフーの画面もどちらも終了できませんでした。
また、aさんのスクリプトでは接続中の画面しか終了できませんでした。
ところで、今使っているパソコンはVISTAですが、もう一台のXPで試し
たら、画面が２つ起動することはありませんでした。これはOSの違いな
のか、私がスクリプトを理解せずにVISTAのほうに間違ったことをした
ためなのか分かりません。このように考えること自体見当はずれかもし
れませんが、未だ解決していないので、ご教示お願いします。
（記憶がはっきりしないのですが、KENTAさんのスクリプトをVISTAで
初めて実行したときは画面は１つしか起動しなかったような気もします
が・・・、はっきりとは思い出せません。）

>これはOSの違いなのか、私がスクリプトを理解せずにVISTAのほうに
>間違ったことをしたためなのか分かりません。
XPとVISTAの環境の違いで、動作が変わるものもあります。
私のOSはXPなので、私の書き込んだスクリプトはXPでは正常に動作しますが、
VISTAで正常に動作するかは分かりません。
ですので、私の書き込んだスクリプトはXPで実行してみることをお勧めします。

Windows Vista対応についての情報 :http://hsp.tv/make/vista.html

自分の所はXP+IE6です。
OSじゃなく、IE7がタブブラウザになったからみたいだね。
http://www.happy2-island.com/vbs/cafe02/capter00711.shtml
に、IE7用の方法みつけた。
起動処理だけ、IE6以下とIE7以上で、少しだけ異なるものにしないといけないみたい。

HSP上からIEのバージョン調べる簡単な方法ないものかな？
強引な方法なら・・・でもセキュリティーの厳しいVistaで動くか？
ん〜〜、Vistaもってねえー orz