HSPTV!掲示板

どうもお世話になっております〜。hirosenzmです。
気になっているんですが、ウィンドウのデザインと言うか、
ウィンドウに画像を使うことってできますかね？
適当なスクリあったら教えて下さい。

検索エンジンで、「HSP リージョン」あたりのキーワードで調べてください。

↑にはウィンドウに画像を使うこと書いてないですよｗ
いい方法ないですかね？

検索した結果をちゃんと見れば書いてあるかと思いますが。
ちゃんと探しもしないうちに「書いてないですよｗ」とか言うのはどうかと。

もっと具体的に、画像とウインドウをどの様にしたいのですか？？？？

だから〜、ウィンドウの枠に画像を使うんですよ。（タイトルバーもふくめて）

>>ウィンドウの枠に画像を使うんですよ。（タイトルバーもふくめて）

ウィンドウの枠に画像を使う事はできません。多分。
諦めるか、ウインドウっぽい物を自作するしか無いと思います。

>>↑にはウィンドウに画像を使うこと書いてないですよｗ

>>だから〜、ウィンドウの枠に画像を使うんですよ。（タイトルバーもふくめて）

これが人に頼みごとする態度ですか。
それですと良い答えは得られないかもしれませんよ。

まずKpanさんの煽っている通りのことでできます。
hirosenzmさんの発言から推測して、そんなに複数のサイトを見ていないのでは、と思います。

>>適当なスクリあったら教えて下さい。

hirosenzmさんからはなるべく自力で問題解決しようという意思はないように取れます。
hirosenzmさんが自分のスキルを伸ばしたいのならスクリプトを教えてもらうのではなく
ヒントに留めておくべきだと思います。

と言いながら

#uselib "user32.dll"
#func SetParent "SetParent" int,int
wx=600:wy=400:titles=29
bgscr 25,wx-6,wy-titles-3
hwnd_=hwnd
syscolor 15:boxf
bgscr 24,wx,wy
oncmd gosub *move,$201
color 0,0,255:boxf 
pos 0,0:color 255,255,255
font "MS UI Gothic",12,1
pos 20,10:mes "Hot Soup Processor ver.3.1"
SetParent hwnd_,hwnd
gsel 25
width ,,3,titles 
color
mes "kjk"
stop
*move
gsel ginfo_act
sendmsg hwnd ,$a1,2,z
return

リージョンではありません
枠を自作した例です。
自力で読解してください。

あなたは小学生と言っていますが嘘でしょう。
あんな高度な技知らないでしょう。
自分も人の事言えないけど、、（HSP暦二年（過度開発））
それはともかく、スプリクトを与える＝敵を増やす
と、思いながらスプリクトを書いてみた。

#uselib "user32.dll"
#func SetParent "SetParent" int,int
wx=640:wy=480:titles=29
bgscr 25,wx-6,wy-titles-3
hwnd_=hwnd
buffer 1
picload "test.bmp"
gsel 25
color 255,255,255:boxf
bgscr 24,wx,wy
oncmd gosub *move,$201
color 0,0,255:pos 0,0 :gcopy 1,0,0,640,480
pos 0,0:color 255,255,255
font "MS UI Gothic",12,1
pos 20,10:mes "Hot Soup Processor ver.3.1"
SetParent hwnd_,hwnd
gsel 25
width ,,3,titles 
color
mes "kjk"
gsel 0,-1
stop
*move
gsel ginfo_act
sendmsg hwnd ,$a1,2,z
return

こんな感じですか？

船丸さん･･･

色々言いたいことがありますが、止めておきます。

それは何ですか？

begriffさんの言いたいことはよくわかります。
船丸さんのスクリプトはそのままでは実行できないので、
誰でも実行できるようにしてほしいです。

そうなら

#uselib "user32.dll"
#func SetParent "SetParent" int,int
wx=640:wy=480:titles=29
bgscr 25,wx-6,wy-titles-3
hwnd_=hwnd
buffer 1
boxf
color 255
line 10,10,100,10
gsel 25
color 255,255,255:boxf
bgscr 24,wx,wy
oncmd gosub *move,$201
color 0,0,255:pos 0,0 :gcopy 1,0,0,640,480
pos 0,0:color 255,255,255
font "MS UI Gothic",12,1
pos 20,10:mes "Hot Soup Processor ver.3.1"
SetParent hwnd_,hwnd
gsel 25
width ,,3,titles 
color
mes "kjk"
gsel 0,-1
stop
*move
gsel ginfo_act
sendmsg hwnd ,$a1,2,z
return

で、良い？

少し書き換えてみた

	#include "user32.as"
	
	#const WM_LBUTTONDOWN    0x0201
	#const WM_NCLBUTTONDOWN  0x00A1
		#const HTCAPTION  0x2
	#const WM_CLOSE          0x0010
	
	screen 0,1,1,2  //未使用
	
	//------------------------------------------------
	bgscr 1,,,2, 100, 100
	picload dir_exe+"\\sample\\demo\\logop.bmp"
	hwnd_base = hwnd
	oncmd gosub *wnd_move, WM_LBUTTONDOWN
	pos 270, 75  :  button gosub "閉じる", *wnd_close
	
	//------------------------------------------------
	bgscr 2, 230, 60, , 10, 80
	SetWindowLong hwnd, -16, 0x56000000
	SetParent hwnd, hwnd_base
	
	//------------------------------------------------
	gsel 1, 1
	gsel 2
	
	while(1)
		color rnd(256),rnd(256),rnd(256)
		x = rnd(ginfo_winx)  :  y = rnd(ginfo_winy)  :  d = 5+rnd(10)
		circle x, y, x+d, y+d
		wait 10
	wend

*wnd_move
	sendmsg hwnd_base, WM_NCLBUTTONDOWN, HTCAPTION, 0
	return

*wnd_close
	PostMessage hwnd_base, WM_CLOSE, 0, 0
	return

aさんのに付け加えてみた。

    #include "user32.as"
    
    #const WM_LBUTTONDOWN    0x0201
    #const WM_NCLBUTTONDOWN  0x00A1
    #const HTCAPTION  0x2
    #const WM_CLOSE          0x0010
    
    screen 0,1,1,2  //未使用
    buffer 3,360+16,148+16
    color
    boxf
    color 255,0,255
    boxf 0,0,16,16
    boxf 360,148,360+16,148+16
    boxf 360,0,360+16,32
    color
    circle 0,0,32,32
    circle 360-16,148-16,360+16,148+16
    circle 360-16,-16,360+16,16
    circle 360-16,16,360+16,48
    //------------------------------------------------
    bgscr 1,360+16,148+16,2
    GetWindowLong hwnd,-20
    SetWindowLong hwnd,-20,stat|0x00080000
    SetLayeredWindowAttributes hwnd,$ff00ff,0,1
    color
    boxf
    pos 8,8
    picload dir_exe+"\\sample\\demo\\logop.bmp",1
    gmode 2,360+16,148+16
    pos 0,0
    gcopy 3,0,0,360+16,148+16
    gsel 1,2
    hwnd_base = hwnd
    oncmd gosub *wnd_move, WM_LBUTTONDOWN
    pos 270+8, 75+8  :  button gosub "閉じる", *wnd_close
    
    //------------------------------------------------
    bgscr 2, 230, 60, , 10+8, 80+8
    SetWindowLong hwnd, -16, 0x56000000
    SetParent hwnd, hwnd_base
    
    //------------------------------------------------
    gsel 1, 1
    gsel 2
    
    while(1)
        color rnd(256),rnd(256),rnd(256)
        x = rnd(ginfo_winx)  :  y = rnd(ginfo_winy)  :  d = 5+rnd(10)
        circle x, y, x+d, y+d
        wait 10
    wend

*wnd_move
    sendmsg hwnd_base, WM_NCLBUTTONDOWN, HTCAPTION, 0
    return

*wnd_close
    PostMessage hwnd_base, WM_CLOSE, 0, 0
    return

萌えてみた。

    #include "user32.as"
    
    #const WM_LBUTTONDOWN    0x0201
    #const WM_NCLBUTTONDOWN  0x00A1
    #const HTCAPTION  0x2
    #const WM_CLOSE          0x0010
    
    screen 0,1,1,2  //未使用
    buffer 4:picload dir_exe+"\\sample\\demo\\jp6girl.bmp"
    buffer 3,280+16,480+16
    color 255,0,255:boxf
    ;
    gmode 2:gcopy 4,0,0,280,480
    ;
    //------------------------------------------------
    bgscr 1,280+16,480+16,2
    GetWindowLong hwnd,-20
    SetWindowLong hwnd,-20,stat|0x00080000
    SetLayeredWindowAttributes hwnd,$ff00ff,0,1
    color
    boxf
    pos 8,8
    gmode 2,280+16,480+16
    pos 0,0
    gcopy 3,0,0,280+16,480+16
    gsel 1,2
    hwnd_base = hwnd
    oncmd gosub *wnd_move, WM_LBUTTONDOWN
    pos 20, 170 :  button gosub "閉じる", *wnd_close
	;
	stop
    
*wnd_move
    sendmsg hwnd_base, WM_NCLBUTTONDOWN, HTCAPTION, 0
    return

*wnd_close
    PostMessage hwnd_base, WM_CLOSE, 0, 0
    return

もう解決したと思うのは僕だけですか？
解決したら質問者本人がここをチェックしてください。と書いてある所にはチェックを入れましたか？