HSPTV!掲示板

レーザーを発射している時にもう一回発射ボタンを押しても無視されてしまいます・・・。
発射している時でも打てるようにするにはどうすれば良いのでしょうか？

*start
	a=100:b=100:c=a+20:d=b
	color 0,0,0
	pos a,b
	mes"あ"
	onkey *osu
*osu
	wait 1
	getkey q,32
	if q=1:{
*yoko
	color 0,0,0
	pos c,d
	mes "A"
	wait 10
	color 255,255,255
	boxf c,d,c+10,d+20
	if c>200{wait 20:goto *start}else:c+10
	goto *yoko
}
	goto *start

初心者なんで基本すぎなこと聞いてたらスミマセン！！

こんなもんでどうでしょ？
１５分で適当に作ったものなんでバグがあると思います…
(^_^;;

	px = 160							;	初期の X,Y 座標
	py = 120

	spd = 4								;	移動の早さ
	tsp = 8								;	弾の速さ

	max = 5								;	弾の最大数

	dim flg,max
	dim tmx,max
	dim tmy,max

	if spd >= tsp{
		dialog "弾の速さよりの自機の速さほうが同じまたは早く設定されています",1,"注意"
	}
	

*main									;	ループ開始
	redraw 0							;	描画を仮想画面だけにする
		color 0,0,0						;	背景を塗りつぶす
			boxf						;		　↓
		pos px,py
			color 255,255,255
			mes "＠→"
			sizex = ginfo(14)
			sizey = ginfo(15)

	repeat max
		if flg(cnt) = 1{
			tmx(cnt) + tsp
			pos tmx(cnt),tmy(cnt)
				color 0,0,255
				mes "―"
			if tmx(cnt) >= 640{
				flg(cnt) = 0
			}
		}
	loop

	redraw 1

	gosub *keychk						;	キー入力チェックへ飛ぶ
	
	wait 1 : goto *main					;	ループの初めへ

*keychk
		stick key,15					
			if key and 1 {				;	and にしてるのは斜め移動のため
				if px <= 0{				;	画面からはみ出すのを防止するため
					px = 0
				}
				else {
					px - spd
				}
			}
			if key and 4 {
				if px >= 640-sizex{
					px = 640-sizex
				}
				else {
					px + spd
				}
			}
			if key and 2 {
				if py <= 0{
					py = 0
				}
				else {
					py - spd
				}
			}
			if key and 8 {
				if py >= 480-sizey{
					py = 480-sizey
				}
				else {
					py + spd
				}
			}

			if key and 16 {
				repeat max
					if flg(cnt) = 0{
						flg(cnt) = 1
						tmx(cnt) = px+sizex
						tmy(cnt) = py
						break
					}
				loop
			}
			
return

＠追記です

スクリプトを見て分かると思いますけど操作方法は

↑　上に移動
←　左に移動
↓　下に移動
→　右に移動

スペース　弾発射

ですよ…

なるほど！！
dim命令とrepeat命令が鍵だったんですね！！
すごく遅くなってごめんなさい。
ありがとうございました！！！！！