HSPTV!掲示板

ネット関係のプログラミングを始めようとおもい
pcbnet2 を使うことにしました

さっそく付属のチャットサンプルを動かしてみようと思ったのですが
127.0.0.1 に接続ができません
ローカルじゃだめなのかなぁ

質問の場所が違うのかもしれませんが、
TCP/IPに強いかたがおられましたら、改善策を教えてください。

・・・TCP/IP まったくの初心者ですがよろしくお願いします。

pcbnet2
http://www.pcbsoft.net/for-hsp-users.html

#include "pcbnet2.as"


#define PORT 3301	;ポート番号


	;///////////////////////////////////////////// 初期化

	randomize

	sdim name,64
	sdim host,256
	sdim msg,256
	sdim memberlist,16000
	sdim buf,2000
	sdim s,2000
	sdim ss,2000

	host="127.0.0.1"
	r=rnd(100)
	name="Test"+r

	title "Simple Chat"
	objmode 2


	;///////////////////////////////////////////// メニュー画面

*menu

	cls 1

	pos 10,10
	mes "接続先:"
	pos 20,30
	input host,200,24,255

	pos 10,70
	mes "ニックネーム:"
	pos 20,90
	input name,200,24,63

	pos 40,150
	objsize 120,24
	button "接続",*connect

	objsel 0
	stop


	;///////////////////////////////////////////// 接続開始

*connect
	if (name="")|(host="") : dialog "必要事項を入力してください" : stop

	cls 1

	tcpopen soc,host,PORT
	if stat : dialog "tcpopenに失敗しました!",1 : end

	mes host+" に接続中..."
*@
	tcpiscon soc
	if stat=0 : wait 1 : goto *@b

	if stat>1 : tcpclose soc : dialog "接続に失敗しました!",1 : goto *menu

	mes "接続が完了しました."
	wait 50

	cls 1
	pos 0,winy-24
	mesbox msg,winx-160,24,1
	pos winx-160,0
	objsize 160,winy
	listbox dummy,0,""

	tcpput "login "+name+"\n",soc
	goto *main



	;///////////////////////////////////////////// メイン

*main
	tcpfail soc
	if stat : tcpclose soc : dialog "接続が切断されました!",1 : end
	tcpgetl buf,1024,soc
	if stat : gosub *recv
	instr a,msg,"\n"
	if a!-1 : gosub *send
	wait 1
	goto *main


*recv
	sdim cmd,1024
	sdim arg,1024
	getstr cmd,buf,0,' '
	getstr arg,buf,strsize

	if cmd="joined" : gosub *joinedmember
	if cmd="left" : gosub *leftmember
	if cmd="msg" : gosub *message
	return

*joinedmember
	memberlist+=arg+"\n"
	objprm 1,memberlist
	objsel 0
	return

*leftmember
	notesel memberlist
	members = noteinfo(0)
	repeat members
		noteget s,cnt
		if s=arg : notedel cnt : break
	loop
	objprm 1,memberlist
	objsel 0
	return

*message
	redraw 2
	pos 0,0
	gcopy 0,0,20,winx,winy-20
	pos 0,winy-24-20
	mes arg
	redraw 1
	return

*send
	s=msg
	instr a,s,"\n"
	getstr ss,s,a+2
	poke s,a,0
	s+=ss
	buf="say "+s+"\n"
	tcpput buf,soc
	objprm 0,""
	return

ためしにサンプルを動作させたところ 127.0.0.1 で接続できました。

ところで、↑にはクライアントのスクリプトしかないようなのですが……
もしかして、通信をするソフトウェアには「サーバ」と「クライアント」があるというところからご存知ないのでしょうか？

よくみたらサーバー用のやつもありました
でも127.0.0.1じゃなくて192.168.0.3で接続したらできました

サーバー用のやつはどうやったら常時起動できるんだろう？

まあもうすこし自分で勉強してみます。