HSPTV!掲示板

グループボックスはどのように作成すればいいのでしょうか？？

まずはじめにGoogle(http://www.google.co.jp/)で「グループボックス　hsp」というキーワードを検索してみてください。
質問する前に自分で調べることはとても重要な作業です。
注意してくださいね。

また、サンプルの中を探してみるのも問題解決には有効な作業です。
HSPエディタのメニューからツール→サンプルスクリプト参照　を開きます。
サンプルスクリプトビューワが起動します。
カテゴリをbasicにして、groupbox.hspを参照してください。

また、もうひとつの解決方法として、line命令を駆使して描画する方法もあります。

すいません。質問の仕方が相当悪かったみたいです。
標準のgroupboxはバグがあるみたいですので、groupbox.hspはあまり見ておりませんでした。
モジュールやlineを使わずに、他のボタン等と同じように
作成する方法があればと思い質問しました。

拡張プラグインを見つけたのでそれを使用しようと思います。
お手数かけました。

line命令での(擬似)作成は以前からやっていたので参考までにどうぞ。

	#module
	
	#const GROUPBOX_LEFT_PADDING	7
	#const GROUPBOX_RIGHT_PADDING	7
	#const GROUPBOX_LEFT_SPACE		3
	#const GROUPBOX_RIGHT_SPACE		3
	#const GROUPBOX_LEFT_OFFSET		(GROUPBOX_LEFT_PADDING + GROUPBOX_LEFT_SPACE)
	#const GROUPBOX_RIGHT_OFFSET	(GROUPBOX_RIGHT_PADDING + GROUPBOX_RIGHT_SPACE)
	#const GROUPBOX_BOTH_OFFSET		(GROUPBOX_LEFT_OFFSET + GROUPBOX_RIGHT_OFFSET)
	
	#deffunc groupbox str _caption, int _width, int _height
	
	r = ginfo_r
	g = ginfo_g
	b = ginfo_b
	x = ginfo_cx
	y = ginfo_cy
	
	;フォントの高さを取得
	mref bmscr, 67
	font_h = bmscr(32)
	bmscr = 0
	
	;キャプションを描画
	syscolor 18
	pos x+GROUPBOX_LEFT_OFFSET, y-font_h/2
	mes _caption
	
	capt_w = ginfo_mesx
	capt_h = ginfo_mesy
	width_ = limit(_width, capt_w+GROUPBOX_BOTH_OFFSET, _width)
	
	;枠の影を描画
	syscolor 22
	pos x+GROUPBOX_LEFT_OFFSET+capt_w+GROUPBOX_RIGHT_SPACE, y+1
	line x+width_, y+1
	line x+width_, y+_height
	line x+1, y+_height
	line x+1, y+1
	line x+GROUPBOX_LEFT_PADDING, y+1
	
	;枠を描画
	syscolor 16
	pos x+GROUPBOX_LEFT_OFFSET+capt_w+GROUPBOX_RIGHT_SPACE, y
	line x+width_-1, y
	line x+width_-1, y+_height-1
	line x, y+_height-1
	line x, y
	line x+GROUPBOX_LEFT_PADDING, y
	
	;ginfo_r, ginfo_g, ginfo_bを元の値に戻す
	;ginfo_cx, ginfo_cyをグループボックスの下の位置にセット
	color r, g, b
	pos x, y+_height
	
	return
	
	#global
	
	
	syscolor 15 : boxf
	
	pos 5,5 : groupbox "hoge", 200, 100