|
 |
|
|
2008/9/8(Mon) 09:39:41|NO.19154
HSPについて （ランチャー
HSPを初めてまもなぃ初心者なんですが、今ランチャーを作っています。
とりあえず以下のスプリクトを書いてみたんですが、設定の保存方法がわかりませんorz
質問の内容は、このスプリクトを実行して設定ボタンを押して、『ボタン１~１０』と書いてぁる画面にいくんですが、
そこの『ボタン１~１０』を変更して、登録ボタンを押すとメインの画面に戻ります。
そのときは一時的に『ボタン１~１０』の内容が変わるんですが、終了して次回起動したときは、当たり前ですが、また初期設定に戻ってしましぃす。
そこで、一度『』の内容を変更したら、その内容を保存して、次回起動時に『』の内容が読み込まれてボタンの文字に反映させるょうにしたいのですがどのように書けばぃいでしょうか??
いろいろと調べて自分なりにやってみたのですが、やはり無理でした。。
わかりづらい質問ですが、どなたかご教授願います。
a = "ボタン1"
b = "ボタン2"
c = "ボタン3"
d = "ボタン4"
e = "ボタン5"
f = "ボタン6"
g = "ボタン7"
h = "ボタン8"
i = "ボタン9"
j = "ボタン10"
*modoru
screen 0,200,150
color 166, 202, 240 : boxf
title "ランチャー"
objsize 50,50
pos 0,0 : button goto ""+a+"",*m1
pos 50,0 : button goto ""+b+"",*m2
pos 100,0 : button goto ""+c+"",*m3
pos 150,0 : button goto ""+d+"",*m4
pos 0,50 : button goto ""+e+"",*m5
pos 50,50 : button goto ""+f+"",*m6
pos 100,50 : button goto ""+g+"",*m7
pos 150,50 : button goto ""+h+"",*m8
pos 0,100 : button goto ""+i+"",*m9
pos 50,100 : button goto ""+j+"",*m10
pos 100,100 : button goto "設定",*setei
pos 150,100 : button goto "終了",*owari
stop
*setei
screen 0,300,290
color 166, 202, 240 : boxf
x = 5
y = 5
pos x,y : input a,70,20
pos x,y+25 : input b,70,20
pos x,y+50 : input c,70,20
pos x,y+75 : input d,70,20
pos x,y+100 : input e,70,20
pos x,y+125 : input f,70,20
pos x,y+150 : input g,70,20
pos x,y+175 : input h,70,20
pos x,y+200 : input i,70,20
pos x,y+225 : input j,70,20
pos 200,260 : button goto "登録(戻る)",*modoru
stop
*m1
stop
*m2
stop
*m3
stop
*m4
stop
*m5
stop
*m6
stop
*m7
stop
*m8
stop
*m9
stop
*m10
stop
*owari
end
| |
|
|
2008/9/8(Mon) 09:48:54|NO.19155
メモリノートパッド命令 を使って、
設定内容をテキストファイルに保存するのが簡単だとおもいます。
note…と付く名前の命令をいくつか組み合わせることになりますので、調べてみてください。
|
|
|
2008/9/8(Mon) 14:41:01|NO.19161
＞メモリノートパッド命令 を使って、
＞設定内容をテキストファイルに保存するのが簡単だとおもいます。
＞note…と付く名前の命令をいくつか組み合わせることになりますので、調べてみてください。
回答していただきありがとぅございます。
メモリーノッドパッド命令を使ってやってみたのですが、『ボタン1』の場所（一箇所）の
内容の保存はできて読み込めました。
ですが、『ボタン2~10』の内容が保存はできても、読み込むときに、うまく表示されません。
『ボタン1~10』までを読み込むと、『ボタン1』の内容に、『ボタン1~10』までの内容が、
すべてつながって表示されてしまします；
それに、『ボタン2~10』までは表示がかわらなぃです。
どなたかご教授ねがぃます；；
ここまではちゃんとできたのですが、これ以降がわかりません；
a = "ボタン1" : k = ""+a+""
b = "ボタン2" : l = ""+b+""
c = "ボタン3" : m = ""+c+""
d = "ボタン4" : n = ""+d+""
e = "ボタン5" : o = ""+e+""
f = "ボタン6" : p = ""+f+""
g = "ボタン7" : q = ""+g+""
h = "ボタン8" : r = ""+h+""
i = "ボタン9" : s = ""+i+""
j = "ボタン10" : t = ""+j+""
notesel k
noteload "notedata.txt" ;データ読み込み
goto ,*modoru
stop
*modoru
screen 0,200,150 ;メイン画面
color 166, 202, 240 : boxf
title "ランチャー"
objsize 50,50
pos 0,0 : button goto ""+k+"",*m1
pos 50,0 : button goto ""+l+"",*m2
pos 100,0 : button goto ""+m+"",*m3
pos 150,0 : button goto ""+n+"",*m4
pos 0,50 : button goto ""+o+"",*m5
pos 50,50 : button goto ""+p+"",*m6
pos 100,50 : button goto ""+q+"",*m7
pos 150,50 : button goto ""+r+"",*m8
pos 0,100 : button goto ""+s+"",*m9
pos 50,100 : button goto ""+t+"",*m10
pos 100,100 : button goto "設定",*setei
pos 150,100 : button goto "終了",*owari
stop
*setei ;設定画面
screen 0,300,290
color 166, 202, 240 : boxf
x = 5
y = 5
pos x,y : input a,70,20
pos x,y+25 : input b,70,20
pos x,y+50 : input c,70,20
pos x,y+75 : input d,70,20
pos x,y+100 : input e,70,20
pos x,y+125 : input f,70,20
pos x,y+150 : input g,70,20
pos x,y+175 : input h,70,20
pos x,y+200 : input i,70,20
pos x,y+225 : input j,70,20
pos 200,260 : button goto "登録(戻る)",*touroku
stop
*m1
stop
*m2
stop
*m3
stop
*m4
stop
*m5
stop
*m6
stop
*m7
stop
*m8
stop
*m9
stop
*m10
stop
*owari
end
*touroku
notesel k
noteadd ""+a+"",0,1
notesave "notedata.txt" ;データ保存
goto ,*modoru
stop
| |
|
|
2008/9/8(Mon) 15:01:59|NO.19162
ちょっと進みましたね。
しかし、メモリノートパッドというものがよく分からないままになってるようです。
メモリノートパッドは、一行単位で文字列を書き込んだり読み出したりできる機能です。
ですから、保存したい文字列を１行と考えてnoteadd命令でメモリノートに次々と追加していって、それをnotesave命令で保存しないといけません。
読み出すときも、いったんメモリノートに指定した文字列変数に読み出して、そこから１行ずつ取り出すようにします。
|
|
|
2008/9/8(Mon) 16:44:49|NO.19166
アドバイスありがとぅございます。
先ほど、ぃろぃろ試したところようやく保存＆読み込みが可能になりました。
しかし、メイン画面の『ボタン1~10』までは保存&読み込みできるのですが、
設定画面には反映させる方法がわかりません；
たとえば、メイン画面の『ボタン１』を設定画面で『メモ帳』に設定するとします。
そして、メイン画面にもどれば『ボタン1』は『メモ帳』に変わります。
また、このまま終了ぜずに、もう一度設定画面をみると、『ボタン１』は『メモ帳』のままです。
ですが、一度終了して再起動すると、メイン画面の表示は読み込みされて『メモ帳』に
なるのですが、設定画面を開くとさっき『メモ帳』だったのがまた『ボタン1』に戻ってしまいます。
ですので、再起動しても設定画面にまで『』の文字を反映させたいのです。
ややこしぃですが、どなたかご教授ねがいます；
↓現在、ここまでできました。
a = "ボタン1"
b = "ボタン2"
c = "ボタン3"
d = "ボタン4"
e = "ボタン5"
f = "ボタン6"
g = "ボタン7"
h = "ボタン8"
i = "ボタン9"
j = "ボタン10"
*yomi
notesel np
noteload "notedata.txt" ;データ読み込み
noteget datak, 0
noteget datal, 1
noteget datam, 2
noteget datan, 3
noteget datao, 4
noteget datap, 5
noteget dataq, 6
noteget datar, 7
noteget datas, 8
noteget datat, 9
goto ,*modoru
stop
*modoru
screen 0,200,150 ;メイン画面
color 166, 202, 240 : boxf
title "ランチャー"
objsize 50,50
pos 0,0 : button goto ""+datak+"",*m1
pos 50,0 : button goto ""+datal+"",*m2
pos 100,0 : button goto ""+datam+"",*m3
pos 150,0 : button goto ""+datan+"",*m4
pos 0,50 : button goto ""+datao+"",*m5
pos 50,50 : button goto ""+datap+"",*m6
pos 100,50 : button goto ""+dataq+"",*m7
pos 150,50 : button goto ""+datar+"",*m8
pos 0,100 : button goto ""+datas+"",*m9
pos 50,100 : button goto ""+datat+"",*m10
pos 100,100 : button goto "設定",*setei
pos 150,100 : button goto "終了",*owari
stop
*setei ;設定画面
screen 0,300,290
color 166, 202, 240 : boxf
x = 5
y = 5
pos x,y : input a,70,20
pos x,y+25 : input b,70,20
pos x,y+50 : input c,70,20
pos x,y+75 : input d,70,20
pos x,y+100 : input e,70,20
pos x,y+125 : input f,70,20
pos x,y+150 : input g,70,20
pos x,y+175 : input h,70,20
pos x,y+200 : input i,70,20
pos x,y+225 : input j,70,20
x = 100
y = 25
objsize x,y
pos 150,265 : button goto "登録して戻る",*touroku
objsize x-50,y
pos 250,265 : button goto "ｷｬﾝｾﾙ",*modoru
stop
*m1
stop
*m2
stop
*m3
stop
*m4
stop
*m5
stop
*m6
stop
*m7
stop
*m8
stop
*m9
stop
*m10
stop
*owari
end
*touroku
notesel np
noteadd ""+a+"",0,1
noteadd ""+b+"",1,1
noteadd ""+c+"",2,1
noteadd ""+d+"",3,1
noteadd ""+e+"",4,1
noteadd ""+f+"",5,1
noteadd ""+g+"",6,1
noteadd ""+h+"",7,1
noteadd ""+i+"",8,1
noteadd ""+j+"",9,1
notesave "notedata.txt" ;データ保存
goto ,*yomi
stop
| |
|
|
2008/9/8(Mon) 16:50:13|NO.19167
a〜jから k〜tを作っていますね。
てことは
a〜jを保存して
読み出したときにk〜tをつくるべきではないでしょうか。
ついでに。
noteload命令は対象のファイルがないとエラーで止まります。
exist命令で対象のファイルがあるかどうか確認してからにしましょう。
ファイルがないなら読み出す代わりに初期値を代入したらよいですね。
|
|
|
2008/9/8(Mon) 17:21:49|NO.19170
a〜jを保存して
読み出したときにk〜tをつくるべきでは? とはわかりやすく言うとどぅいう意味でしょぅか？
ぃろぃろ考えたのですが、ょくわかりません；；
度々悪いですが、ご教授ねがいますorz
|
|
|
2008/9/8(Mon) 17:47:46|NO.19171
すみません 私が読み間違えてました
orz
最初のスクリプトでは
一番最初に a に文字列を代入してから、それを使って k の文字列を作っていましたね。
なので、
a を保存しておいて、
スクリプトの最初で a を代入する代わりにファイルから a を読み出し、
その a を使って k の文字列を代入すると良かったのではないでしょうか。
|
|
|
2008/9/8(Mon) 18:51:22|NO.19175
わかりやすぃアドバイスをしていただきありがとぅございます。
おかげ様で、納得のいくスクリプトを書くことができました＾＾
それに、HSPの難しさ&面白さがょくわかった気がします。
本当にありがとぅございます!
これからも、ちょっとづつ頑張って勉強していきたいと思います。
これができたスクリプトです。（これから改良していきたいと思います!）
*yomi ;データ読み込み
notesel np
noteload "notedata.txt"
noteget datak, 0 : noteget a,0
noteget datal, 1 : noteget b,1
noteget datam, 2 : noteget c,2
noteget datan, 3 : noteget d,3
noteget datao, 4 : noteget e,4
noteget datap, 5 : noteget f,5
noteget dataq, 6 : noteget g,6
noteget datar, 7 : noteget h,7
noteget datas, 8 : noteget i,8
noteget datat, 9 : noteget j,9
goto ,*modoru
stop
k = ""+a+""
l = ""+b+""
m = ""+c+""
n = ""+d+""
o = ""+e+""
p = ""+f+""
q = ""+g+""
r = ""+h+""
s = ""+i+""
t = ""+j+""
*modoru ;メイン画面
screen 0,200,150
color 166, 202, 240 : boxf
title "ランチャー"
objsize 50,50
pos 0,0 : button goto ""+datak+"",*m1
pos 50,0 : button goto ""+datal+"",*m2
pos 100,0 : button goto ""+datam+"",*m3
pos 150,0 : button goto ""+datan+"",*m4
pos 0,50 : button goto ""+datao+"",*m5
pos 50,50 : button goto ""+datap+"",*m6
pos 100,50 : button goto ""+dataq+"",*m7
pos 150,50 : button goto ""+datar+"",*m8
pos 0,100 : button goto ""+datas+"",*m9
pos 50,100 : button goto ""+datat+"",*m10
pos 100,100 : button goto "設定",*setei
pos 150,100 : button goto "終了",*owari
stop
*setei ;設定画面
screen 0,300,290
color 166, 202, 240 : boxf
x = 5
y = 5
pos x,y : input a,70,20
pos x,y+25 : input b,70,20
pos x,y+50 : input c,70,20
pos x,y+75 : input d,70,20
pos x,y+100 : input e,70,20
pos x,y+125 : input f,70,20
pos x,y+150 : input g,70,20
pos x,y+175 : input h,70,20
pos x,y+200 : input i,70,20
pos x,y+225 : input j,70,20
x = 100
y = 25
objsize x,y
pos 150,265 : button goto "登録して戻る",*touroku
objsize x-50,y
pos 250,265 : button goto "ｷｬﾝｾﾙ",*modoru
stop
*m1
stop
*m2
stop
*m3
stop
*m4
stop
*m5
stop
*m6
stop
*m7
stop
*m8
stop
*m9
stop
*m10
stop
*owari
end
*touroku ;データ保存
notesel np
noteadd ""+a+"",0,1
noteadd ""+b+"",1,1
noteadd ""+c+"",2,1
noteadd ""+d+"",3,1
noteadd ""+e+"",4,1
noteadd ""+f+"",5,1
noteadd ""+g+"",6,1
noteadd ""+h+"",7,1
noteadd ""+i+"",8,1
noteadd ""+j+"",9,1
notesave "notedata.txt"
goto ,*yomi
stop
| |
|
|
2008/9/8(Mon) 21:10:48|NO.19195
・ω・ ♪ おめでとうございます。
では、せっかくなので ひとつおまけを。
noteloadの行を このようにしてみてください。
ファイルがなくても エラーにならなくなります。
exist "notedata.txt"
if strsize>0 {
noteload "notedata.txt"
}else{
repeat 10 : np+=strf("未登録%d\n",cnt) : loop
}
|
|
|
2008/9/8(Mon) 21:26:29|NO.19202
おまけありがとぅございます (^-^*)♪
ではまた機会がありましたら、そのときはよろしくお願いします。
|
|
|
2008/9/9(Tue) 01:51:54|NO.19248
配列を使うことを覚えましょう。
docs\hspprog.htmの「２．スクリプト記述の基本」の「配列変数」参照。
nbtn=10
sdim btn,64,nbtn
sdim inp,64,nbtn
notesel np
noteload "notedata.txt"
repeat nbtn
noteget btn.cnt,cnt
loop
*modoru ;メイン画面
screen 0,200,150
color 166, 202, 240 : boxf
title "ランチャー"
objsize 50,50
repeat nbtn
pos (cnt\4)*50,cnt/4*50
button btn.cnt,*m
loop
pos (nbtn\4)*50,nbtn/4*50 : button goto "設定",*setei
pos ((nbtn+1)\4)*50,(nbtn+1)/4*50 : button goto "終了",*owari
stop
*setei ;設定画面
screen 0,300,290
color 166, 202, 240 : boxf
x = 5
y = 5
repeat nbtn
inp.cnt=btn.cnt
pos x,y: input inp.cnt,70,20
y+=25
loop
x = 100
y = 25
objsize x,y
pos 150,265 : button goto "登録して戻る",*touroku
objsize x-50,y
pos 250,265 : button goto "ｷｬﾝｾﾙ",*modoru
stop
*m
i=stat ;押されたボタンのオブジェクトID
dialog btn.i
stop
*owari
end
*touroku ;データ保存
notesel np
repeat nbtn
btn.cnt=inp.cnt
noteadd btn.cnt,cnt,1
loop
notesave "notedata.txt"
goto *modoru
|
|
|
2008/9/9(Tue) 11:20:08|NO.19257
＞配列を使うことを覚えましょう。
＞docs\hspprog.htmの「２．スクリプト記述の基本」の「配列変数」参照。
プログラミング・マニュアルがあったんですか~。
初めてしりました（(＠Д＠；）
見たところかなりわかりやすく書いてあるので、
ここを見ながら配列変数を勉強していきたぃと思います。
アドバイスありがとぅございました＾＾
|
|
|
2008/9/9(Tue) 19:47:16|NO.19267
>プログラミング・マニュアルがあったんですか~。
>初めてしりました（(＠Д＠；）
じゃあ、これも知らないと思うので書いておきます。
index.htm
うーん、一見、無意味な書き込みだなあ。わかりますよね？
|
|
|
2008/9/9(Tue) 19:54:21|NO.19268
ありがとぅございます＾＾
総合インデックスにはぃろんなことが書いてあるんですね~。
参考にしたぃと思います。
|
|
|
2008/9/10(Wed) 20:25:25|NO.19326
質問ですorz
配列変数もだいぶ理解できて、順調に改良していたんですが・・
またまた行き詰ってしまぃましたorz
gialog,16,で開いたファイルのパス名?が『refstr』に代入されますょね？
次に『refstr』に代入されたファイルのパス名?の保存がしいたぃのです。
自分なりにぃろぃろ試したんですが、やっぱりできません;
どなたかご教授願います。。
↓現在のスクリプトです。（ょくわからなぃのでかなり中途半端です;;）
nbtn=10
exist "設定保存用 テキスト.txt" ;テキストファイルのチェック
if strsize= 0 :goto ,*yomi
if strsize=-1 : dialog "データが読み込めないので、設定が初期化されました",1,"設定の初期化" : goto ,*syokika
*yomi
pro=refstr
sdim btn,64,nbtn
sdim inp,64,nbtn
sdim pro,64,nbtn
sdim butn,64,nbtn
notesel np
noteload "設定保存用 テキスト.txt"
repeat nbtn
noteget btn.cnt,cnt+1
noteget pro.cnt,cnt+12
loop
noteget butn,11
*modoru ;メイン画面
screen 0,200,300
color 166, 202, 240 : boxf
title "ランチャー"
objsize 100,50
repeat nbtn
pos (cnt\2)*100,cnt/2*50
button btn.cnt,*m
loop
pos nbtn*0,nbtn/4*125 : button goto "設定",*setei
pos (nbtn/4)*50,nbtn/4*125 : button goto "終了",*owari
stop
*setei ;設定画面
pro=refstr
screen 0,400,290
color 166, 202, 240 : boxf
x = 5
y = 5
repeat nbtn
inp.cnt=btn.cnt
pos x,y : input inp.cnt,105,22
pos x+110,y+3 : input pro.cnt,208,16
objsize 65,21
pos x+324,y : button butn,*b
y+=25
loop
x = 320
y = 34
objsize x,y
pos 0,257 : button goto "登録して戻る",*touroku
objsize x-240,y
pos 320,257 : button goto "キャンセル",*modoru
stop
*b
dialog "exe", 16, ""
if stat=0 : goto,*setei
if stat=1 : goto,*setei
stop
*m
i=stat ;押されたボタンのオブジェクトID
exec pro.i
stop
*owari
end
*touroku ;データ保存
notesel np
repeat nbtn
btn.cnt = inp.cnt
noteadd btn.cnt,cnt+1,1
noteadd pro.cnt,cnt+12,1
loop
notesave "設定保存用 テキスト.txt"
goto *modoru
*syokika
notesel np
noteadd "※このテキストは設定保存用ですので、削除しないでくださぃ。（削除すると、設定が初期化されます）"
repeat nbtn
a = int(cnt)+1
noteadd "ボタン"+a+"",cnt+1,1
loop
noteadd "参照",11,1
notesave "設定保存用 テキスト.txt"
goto *yomi
| |
|
|
2008/9/10(Wed) 22:08:37|NO.19330
*b
objid=stat ;押されたボタンのオブジェクトID
dialog "exe", 16, ""
if stat=1 {
i=objid/3
pro.i=refstr
objprm i*3+1,pro.i ;入力ボックスにpro.iをセットする
}
stop
ここでは「pro」を使うべきではなく、
将来、書き直されることになるはずです
（ここの「pro」を生かしてほかを直すという選択肢もあります）。
ほかはデバッグに属することなので、ご自分で。
でも、筋がいいですね。教えがいがあります。
|
|
|
2008/9/10(Wed) 22:55:45|NO.19331
>ょくわからなぃのでかなり中途半端です
パス名の記憶方法よりこちらを先に質問するべきです。
すべてが理解できれば、パス名の記憶方法は質問せずに
済んだ可能性もあります。
|
|
|
2008/9/10(Wed) 23:30:16|NO.19332
設定ファイルが保存されませんが、原因はdialog,16によって
カレントディレクトリが変わるためです。
回避方法は２つあります。
１ 冒頭で例えば「curdir=dir_cur」としてカレントディレクトリを記憶しておき、
notesaveの前に「chdir curdir」を実行する
２ フルパスで扱う
例えば、冒頭で「file=dir_cur+"\\設定保存用 テキスト.txt"」としておき、
すべての「"設定保存用 テキスト.txt"」を「file」に置き換える
ファイル名を変えたくなった場合に簡単に変えられる２がお勧めです。
|
|
|
2008/9/11(Thu) 00:12:01|NO.19333
アドバイスありがとぅございます。
また質問なのですが、
i=objid/3
pro.i=refstr
objprm i*3+1,pro.i
この部分がょく理解できませんorz
① i=objid/3 なぜobiidを３で割るんのですか?
② objprm i*3+1,pro.i ここでまたi(obiid)を元にもどしてさらに『+1』をする理由はなんですか？
ホント初心者でわからなぃことだらけなんですが、ご教授くださぃorz
それと、できればフルパスで扱う方法をもう少し詳しく教えていただけると幸いです。
>ょくわからなぃのでかなり中途半端です
これは、パス名の保存に関係してる所のことで、
『私はまだパス名の保存方法をしらなぃまま保存しょうとしていたので、
変な所や余分なところがいっぱぃあるかもです。。』とぃうことです。
|
|
|
2008/9/11(Thu) 00:45:11|NO.19334
長いので一部省略しましたが、下を見ると３つで１つの項目を処理しています。
オブジェクトを使えば、IDは増えていきますので割る3をしているのだと思います。
+1をしているのは、２番目のinput pro.cnt,208,16の表示を変更する為のものです。
+2ではないのは、IDが0から始まっているからです。
*setei
repeat nbtn
input inp.cnt,105,22
input pro.cnt,208,16
button butn,*b
loop
↓オブジェクトIDのイメージ
（設定画面にて）
0, 1, 2 //ボタン1
3, 4, 5 //ボタン2
6, 7, 8 //ボタン3
9,10,11 //ボタン4
12,13,14 //ボタン5
15,16,17 //ボタン6
18,19,20 //ボタン7
21,22,23 //ボタン8
24,25,26 //ボタン9
27,28,29 //ボタン10
30,31 //登録＆キャンセル
こんなもんでしょうか？
|
|
|
2008/9/11(Thu) 01:08:06|NO.19335
わかりやすく説明していただき、ぁりがとぅございます。
まだなんとなくですが、理解できました。
では、またがんばりたぃと思います。
|
|
|
2008/9/11(Thu) 01:10:23|NO.19336
>� �i=objid/3 なぜobiidを３で割るんのですか?
>�◆�objprm i*3+1,pro.i ここでまたi(obiid)を元にもどして
>さらに『+1』をする理由はなんですか？
オブジェクトIDは宣言した順に振られていきます。
最初の「input inp.cnt,105,22」のオブジェクトIDは0
最初の「input pro.cnt,208,16」のオブジェクトIDは1
最初の「button butn,*b」のオブジェクトIDは2
２番目の「input inp.cnt,105,22」のオブジェクトIDは3
２番目の「input pro.cnt,208,16」のオブジェクトIDは4
２番目の「button butn,*b」のオブジェクトIDは5
３番目の「input inp.cnt,105,22」のオブジェクトIDは6
以下略
したがって、押されたボタンのオブジェクトIDは
2,5,8,11,……のいずれかになります。
これを３で割ると
0,1,2,3,……となり、押されたボタンに対応する配列の要素番号となります。
要素番号を３倍して１を加えると
1,4,7,10,……となり、「input pro.cnt,208,16」のオブジェクトIDになります。
objidから1を引いた値を使っても同じです。
「objid/3」の結果がなぜ「0,1,2,3,……」になるかは
実数型との絡みでややこしい問題をはらんでいますが、ここでは
「整数型数値を割ったり掛けたりした結果は整数型になり、小数以下が切り捨てられる」と
覚えてください。
興味があるなら、詳しくは以下のスレッドで論じられています。
http://hsp.tv/play/pforum.php?mode=all&num=18847
>それと、できればフルパスで扱う方法をもう少し詳しく教えていただけると幸いです。
こういう質問が一番困るんですよね。回答を推敲している間に
１時間くらい立ってしまいました。
「もう少し詳しく」では何を答えればいいのかわかりません。
私には「どう直せばいいか」について疑問の余地があるとは思えませんし、
その意味について知りたいのなら、もっと具体的な質問ができるはずです。
もっとも、F1を押したり、プログラミング・マニュアルを読んだり、
インターネット検索をやればわかるようなことを質問されても困りますが。
| |
|
|
2008/9/11(Thu) 23:54:30|NO.19415
アドバイスぁりがとぅございます。
自分なりにぃろぃろやってみた結果、なんとかランチャーらしくなってきました。
本当にぁりがとぅございました。
また別の質問をするかもですが、そのときはよろしくお願いします。
|
|
HSP ランチャー
