HSPTV!掲示板

最近質問多くてすいません

以前　

　TrackPopupMenuでポップアップメニューを表示すると
　戻り値が返ってくるのを待つ＝処理がとまる

ということをここで教えていただきました

用は↓

#include "user32.as"

	onclick gosub *onjump
	onexit *exit

	//メインのメニュー
	CreatePopupMenu
	hMenu_0 = stat
		AppendMenu hMenu_0, 0,1, "メニュー項目 1"
		AppendMenu hMenu_0, $800, 0, ""
		AppendMenu hMenu_0, 0,2, "メニュー項目 2"

*main
	c++
	title ""+c
	await 5
goto *main

*onjump
	if wparam = 2 {
		TrackPopupMenu hMenu_0, $100, ginfo(0), ginfo(1), 0, hwnd, 0
		if stat = 0 : return

		dialog "メニュー項目 "+stat+" を選択！"
		return
	}
return

*exit
	//メニューの破棄
	DestroyMenu hMenu_1
	end

というスクリプトで、右クリックでメニューを表示すると
カウントがストップするということです

で、今回はポップアップメニューを表示してもカウントを続行させたいのですが、

多分
①右クリックしたら、メニューを表示だけしてメインルーチンに戻る
②メニューがクリックされたらoncmdで判定用のルーチンに飛んで
　どのメニューが押されたか判定する

という方法で何とかできないかなーと思い
http://msdn.microsoft.com/ja-jp/library/cc430229.aspx
でそれっぽい関数がないか探していたのですがなかなか良い方法が見つかりません

どなたか方法が分かる方はいらっしゃいませんか？　＞＜

Win32APIのSetTimer関数を呼んで、WM_TIMERメッセージを取得して処理を行えばいいです。

NewMonkeyさんいつもすいません(^ ^;)
以下のようにスクリプトを組みなおしました
こんな感じでしょうか？

#include "user32.as"

	onclick gosub *onjump
	oncmd gosub *timer, $113

	onexit *exit

	//メインのメニュー
	CreatePopupMenu
	hMenu_0 = stat
		AppendMenu hMenu_0,0,1,"メニュー項目 1"
		AppendMenu hMenu_0,$800,0, ""
		AppendMenu hMenu_0,0,2,"メニュー項目 2"
	//タイマーをセット 50msごとにカウントを+1
	SetTimer hwnd,1,50,0

	stop
	
*timer
	c++
	title "count="+c
	return

*onjump
	if wparam = 2 {
		TrackPopupMenu hMenu_0, $100, ginfo(0), ginfo(1), 0, hwnd, 0
		if stat = 0 : return

		dialog "メニュー項目 "+stat+" を選択！"
		return
	}
return

*exit
	//メニューの破棄
	DestroyMenu hMenu_1

忘れてました
最後にタイマーのメモリも開放したほうがいいですよね


・・・関数を探してきます(^ ^;)

よしよし、その心がけだ。
しっかり開放していないとメモリリークを起こすからな。

みつけました!
最後の行に

KillTimer hwnd,1

で完成としてよいでしょうか？

ＯＫ、それで完了。

おお～やっと完成!!
NewMonkeyさん　checkさんありがとうございました^ ^

解決

僕が実験してみたスクリプトとほぼ同じです^^
あと最後にendを。終了できないので。

それと、もし目的が
「ペイントみたいに選択されているメニューの説明をステータスバーなどに表示したい」ということなら
WM_MENUSELECTメッセージを処理したほうがいいと思う。