HSPTV!掲示板

地味〜な質問ですが、
現在のフォントサイズやスタイルが代入されているシステム変数などはありますか。
なければフォントサイズを設定する命令を作って、

#module
 #deffunc setFontSize int In_fontsize
  fontsize = In_fontsize
  font "", fontsize
 return
 #defcfunc getFontSize
 return fontsize
#global
setFontSize 100
mes getFontSize()

とすれば良い話なのですが…

こちらのページが参考になると思います。
http://lhsp.s206.xrea.com/hsp_string.html#8

	#module
	#deffunc set_stat int ret_stat
	return ret_stat


	#deffunc set_refstr str ret_refstr
	return ret_refstr


	#deffunc font_get local bmscr, local font_name, local font_size, local font_deco
	;――――――――――――――――――――――――――――――――――――――――
	;		font_get
	;現ウィンドウのフォント名をrefstrに、サイズ＆修飾をstatに、それぞれ返す命令
	;サイズはstatの上位2Byte(= stat / $10000)、修飾は下位2Byte(= stat \ $10000)に返す
	;――――――――――――――――――――――――――――――――――――――――
	mref bmscr, ginfo_sel + 96

	sdim font_name
	getstr font_name, bmscr, $E0
	set_refstr font_name

	font_size = -bmscr.49

	font_deco = 0
	if bmscr.53 = 700 : font_deco + 1
	if peek(BMSCR.54, 0) = 1 : font_deco + 2
	if peek(BMSCR.54, 1) = 1 : font_deco + 4
	if peek(BMSCR.54, 2) = 1 : font_deco + 8
	if peek(BMSCR.55, 2) = 4 : font_deco + 16

	set_stat font_size * $10000 + font_deco
	return
	#global



	randomize
	k = rnd(31)
	font "HG正楷書体-PRO", 23, k
	font_get
	mes "フォント\t：" + refstr
	mes "サイズ\t：" + (stat / $10000)
	mes "修飾\t：" + (stat \ $10000)
	mes "つまり\t：" + k

　匿名希望さんの書かれた参照先を元に作ってみましたが、ハンドル番号の方が汎用性が
高かったかもしれません。

BMSCR構造体なんてものまったく知りませんでした。
mrefを使えるとかっこいいですよね…
ともかく　ありがとうございました！