複数の画像を１つにまとめちゃうと、あとで編集しなおすときに面倒だから
複数の画像を、１つのバッファに読み込めば良いんじゃないかなぁ？
メモリ効率とか詳しくないけど、多分こんな感じ？
//定数定義
#enum メインスクリーン = 0
#enum サブスクリーン
#enum 画像読込バッファ
// 画像サイズ取得
dirlist 画像リスト, "*.bmp"
画像数 = stat
if 画像数 <= 0 : dialog "スクリプトと同じフォルダに画像を入れてね。"
buffer 画像読込バッファ
notesel 画像リスト
repeat 画像数
noteget 画像ファイル名( cnt ), cnt
picload 画像ファイル名( cnt )
画像サイズW( cnt ) = ginfo( 12 )
画像サイズH( cnt ) = ginfo( 13 )
画像座標X( cnt ) = 画像座標合計
画像座標合計 += 画像サイズW( cnt )
loop
//バッファサイズ計算
repeat 画像数
バッファW += 画像サイズW( cnt )
if バッファH < 画像サイズH( cnt ) : バッファH = 画像サイズH( cnt )
loop
buffer 画像読込バッファ, バッファW, バッファH
//画像読込
repeat 画像数
pos 画像座標X( cnt ), 0
picload 画像ファイル名( cnt ), 1
loop
//画像読出命令
goto *main
#deffunc 画像読出 int 画像番号
gcopy 画像読込バッファ, 画像座標X( 画像番号 ),0, 画像サイズW( 画像番号 ), 画像サイズH( 画像番号 )
return
//ここからはデモプレイ
*main
screen サブスクリーン, バッファW, バッファH, 8
gcopy 画像読込バッファ, 0,0, バッファW, バッファH
title "パレット"
gsel メインスクリーン
title "デモプレイ中"
repeat
pos rnd( 640 ), rnd( 480 )
画像読出 rnd( 画像数 )
await 1
loop
同じフォルダ内の画像(bmpファイル)を１つのバッファにまとめるよ。
デモプレイではバッファから画像を読み出してランダムに配置するよ。
よかったらこれを元にいろいろやってみてね☆ふぁいとっ
複数の画像の読み込みについて
