HSPTV!掲示板

再生速度を自由に変更し遅くしたいのですがどのようにしたら実現できますか
宜しくお願いします。

何を再生したいのか謎ですが。
もうちょっと具体的に示すとレスがつきやすいです。


ということはさておき、MCIであれば「set〜speed」で変更可能です。

mci "open xxx.mp3 alias media"
mci "play media"
mci "set media speed 500"  // 単位は10％　500なら0.5倍速

と言った感じで。 動画でも音声でも同じだと思います。確か。
もしMCI命令を知らないのであればあとは調べてください。


ただMP3の再生速度を変更すると不具合があるようですね。
http://hsp.tv/play/pforum.php?mode=pastwch&num=6914

ありがとうございます　
とても参考になりました，再生速度を変えることが確認できました。

ご指摘のＵＲＬですがＭＰ３は速度を遅くできますがＷＡＶでは速度に変化がありませんでした
どのようにすればＷＡＶでも再生速度が変化するでしょうか
宜しくお願いします。

　

#usecom IGraphBuilder "{56A868A9-0AD4-11CE-B03A-0020AF0BA770}"
#comfunc RenderFile 13 wstr

#usecom IMediaPosition "{56A868B2-0AD4-11CE-B03A-0020AF0BA770}"
#comfunc put_Rate 14 double

#usecom IMediaControl "{56A868B1-0AD4-11CE-B03A-0020AF0BA770}"
#comfunc Play 7

	dialog "wav",16
	if stat=0 : end

	newcom com,"{E436EBB3-524F-11CE-9F53-0020AF0BA770}"
	RenderFile com,refstr
	put_Rate com,0.5
	Play com
	stop

COMによる解決法が提示されていますが，MCIの方も一応

MCIのopenは何も指定しないと再生するファイル毎の既定のデバイスで再生しようとします
既定のデバイスは通常，MIDIなら「Sequencer」，WAVEなら「waveaudio」，…と言った感じです
「waveaudio」は再生速度を変えることが出来ないデバイスっぽいです
一方，MP3などを開く時は既定は大抵「MPEGVideo」または「MPEGVideo2」で，これらは再生速度が変えられるデバイスのようです（マシンによってこれらのデバイスがあったりなかったりします）

このデバイスはMP3を始めとして殆どのメディアファイルを開くことが出来ますので，WAVEだろうと「MPEGVideo」を用いて開けば再生速度を変えられたりします

	dev = ""
	mci "sysinfo all quantity" : devNum = stat
	repeat devNum 
		mci "sysinfo all name "+(cnt+1)
		tstr = getpath( refstr, 16 )
		if ( instr( tstr, 0, "mpegvideo" ) >= 0 ) : dev = refstr
	loop
	if ( dev == "" ) : dialog "デバイスmpegvideoがみつかりません" : end
	mes "選択されたデバイス "+dev

	dialog "wav", 16
	if ( stat == 0 ) : end

	mci "open \""+ refstr +"\" alias media type "+ dev +" wait"
	mci "play media"
	mci "set media speed 500"

すは゛らしい
おかげさまで速度を変えることができました
ありがとうございます。