HSPTV!掲示板

IEなどのブラウザでCtrl+Fを押すと文字検索欄みたいのが出てきますよね？
これをIEコンポネート内で実行させたいんです！
おねがいします！！

失礼しました。コンポーネントでしたｗ

HSPに付属しているヘルプブラウザ「HSP Document Library」(以下HDL)では、
IEコンポーネントを使用しており、Ctrl+Fの検索に対応しています。
HDLはソースコードが公開されており、

HSPインストールフォルダ\hspsdk\hdl\hdl_browser.hsp

に存在しています。

そこから、検索に対応するための最低限のソースコードを抜き出しました。

#usecom IOleInPlaceActiveObject "{00000117-0000-0000-C000-000000000046}"
#comfunc OIPAO_TranslateAccelerator 5 var

	axobj ie, "Shell.Explorer.2", 640, 480
	
	// キー操作用
	querycom ieOIPAO, ie, IOleInPlaceActiveObject
	onkey gosub *pushkey

	// スクリプトエラーダイアログ非表示
	ie("Silent") = 1
	// ナビゲート
	ie->"Navigate" "http://hsp.tv/play/pforum.php"
	
stop

// ショートカットキーの処理
*pushkey
/*
	key patch
	9	Tab
	27	Esc
	46	Del
	116	F5
*/
	if varuse(ieOIPAO) {
		// Ctrlキーと同時押しの場合、メッセージ処理
		getkey k, 17
		// ただし下記との組み合わせは無効化
		if wparam = 'N' : k = 0
		if wparam = 'O' : k = 0
		if wparam = 'S' : k = 0
		// コンテナからのアクセラレータキーメッセージ処理
		if (wparam == 9) | (wparam == 27) | (wparam == 46) | (wparam == 116) | k {
			a = 0, $100, wparam, lparam, 0, 0, 0
			OIPAO_TranslateAccelerator ieOIPAO, a
		}
	}
return

他にも自前ブラウザ作成に有用な情報が多いのでHDLのソースコード
を見ておくことをお勧めします。

ありがとうございます。

やってみます。