HSPTV!掲示板

タブコントロールのフォントって変えられないでしょうか?
前、参考にしていたサイトが消えてしまってわからないんです。
教えてもらえると、幸いです。

このサイトはどうでしょうか？
http://chokuto.ifdef.jp/urawaza/setfont.html

ストックを使う方法と、自分でフォントハンドルを作る方法。

#include "GDI32.AS"

screen 0
GetStockObject 17:hFont(0)=stat//ストックを使う
pos 0,0:winobj "systabcontrol32", "", 0,0x50000000,ginfo(12),ginfo(13)
hTab = objinfo_hwnd(stat)
sendmsg hTab, $30,hFont(0)//フォント設定
dim tci, 7
repeat 5
	New_tabn= "タブ"+(cnt+1)
	tci = 0x0001, 0, 0, varptr(New_tabn), strlen(New_tabn)
	sendmsg hTab,0x1307,cnt, varptr(tci)
loop
screen 1
FaceName="ＭＳ 明朝"
LOGFONT(0)=12//lfHeight		フォントの高さ
LOGFONT(1)=10//lfWidth		フォントの幅
LOGFONT(2)=0//lfEscapement
LOGFONT(3)=0//lfOrientation
LOGFONT(4)=0//lfWeight
LOGFONT(5)=0//lfItalic
LOGFONT(6)=0//lfUnderline
LOGFONT(7)=0//lfStrikeOut
LOGFONT(8)=128//lfCharSet(SHIFTJIS_CHARSET)
LOGFONT(9)=0//lfOutPrecision
LOGFONT(10)=0//lfClipPrecision
LOGFONT(11)=0//lfQuality
LOGFONT(12)=0//lfPitchAndFamily
LOGFONT(13)=0//lfFaceName
poke LOGFONT,28,FaceName
CreateFontIndirect varptr(LOGFONT):hFont(1)=stat//自分で作る
pos 0,0:winobj "systabcontrol32", "", 0,0x50000000,ginfo(12),ginfo(13)
hTab = objinfo_hwnd(stat)
sendmsg hTab, $30,hFont(1)//フォント設定
dim tci, 7
repeat 5
	New_tabn= "タブ"+(cnt+1)
	tci = 0x0001, 0, 0, varptr(New_tabn), strlen(New_tabn)
	sendmsg hTab,0x1307,cnt, varptr(tci)
loop
onexit *exit
stop
*exit
	//ストックオブジェクトは削除しなくてもいい。(しても問題ない)
	DeleteObject hFont(1)//フォントハンドル削除(絶対に)
end