HSPTV!掲示板

現在、リストボックスにフォルダリストを作りそのリストを受け渡したいと考えていました。
しかし、うまく変数が渡せていないのかリストの情報が受け渡せません。どこがいけないのでしょうか？

#include "shell32.as"
objsize 380
	para_folder_list=""
	listbox a,200,para_folder_list
	hListbox = objinfo(stat, 2)
	button gosub"フォルダを追加(&A)",*add_folder_para
	button gosub"フォルダを削除(&D)",*del_folder_para
	button "送信",*submit
	
	stop
*add_folder_para
	
	
	para_folder_path=""
	dim bi,8
	sdim sztmp,$206
	ttl="フォルダ選択"
	bi=0,0,varptr(sztmp),varptr(ttl),1,0,0,0
	SHBrowseForFolder varptr(bi)
	idl=stat
	SHGetPathFromIDList idl,varptr(sztmp)
	if stat:para_folder_path=sztmp
	if (para_folder_path==""){
	return
	}
	sendmsg hListbox, $180, , para_folder_path
	
	return
	
*del_folder_para
	
	sendmsg hListbox, $188
	sendmsg hListbox, $182, stat
	
	return
	
*submit
	dialog para_folder_list

SendMessageを使い、上から一つずつ文字を取得していくといいです。
あと、listbox命令のの第3引数は変数型ではなくて文字列型なので、
変数を指定してもその変数は変更されません。

//(〜省略)
*submit
sendmsg hListbox, $18B//LB_GETCOUNT
para_folder_list=""
text=""
notesel para_folder_list
repeat stat
sendmsg hListbox ,$189,cnt,varptr(text)//LB_GETTEXT
	noteadd text,-1,0
loop
dialog para_folder_list