HSPTV!掲示板

pgetとpsetを使ってみたのですが、
画像ファイルを選択してから、画像が表示されるまで2秒ぐらいかかります。
何故でしょうか？

dialog "",16
if stat=0:end
fileimage=refstr

buffer 1
picload fileimage

xsize=ginfo_winx
ysize=ginfo_winy
screen 0,xsize,ysize
gsel 1

gsel 0:redraw 0
repeat ysize
gsel 1
ycnt=cnt

repeat xsize
pget cnt,ycnt
赤(cnt)=ginfo_r:緑(cnt)=ginfo_g:青(cnt)=ginfo_b
loop

gsel 0

repeat xsize
color 赤(cnt),緑(cnt),青(cnt)
pset cnt,ycnt
loop

loop
redraw 1

単純に1ドットずつ処理をする事に時間がかかるからです。

例えていうのならば、豆を一個ずつ拾う(pget)・置く(pset)とするよりも
豆の入った器を移動させる(gcopy等)方が早い、といった感じでしょうか。


ドット単位での処理ならVramデータにpeek・pokeでアクセスする方が速いです。
それでもやはりgcopy等の方が高速ですが。。。

実行してみましたが、このスクリプトはたった2行にできますよ。
2行にすると、こうなります。

dialog "",16
picload refstr

>ドット単位での処理ならVramデータにpeek・pokeでアクセスする方が速いです。
どうやるのですか？
できれば、スクリプトを載せてもらうと幸いです。

ゆーさんのソースを元にpeek,pokeバージョンにしてみました。

dialog "",16
if stat=0:end
fileimage=refstr

buffer 1
picload fileimage

xsize=ginfo_winx
ysize=ginfo_winy
screen 0,xsize,ysize
gsel 1

gsel 0:redraw 0
mref vram0, 66;
gsel 1;
mref vram1, 66;

vwidth = ( (xsize*3) + 3 ) & 0xFFFFFFFC;

repeat ysize
	index_h = cnt * vwidth;
	repeat xsize
		index = cnt*3 + index_h;
		poke vram0, index, peek(vram1, index);		// B
		poke vram0, index+1, peek(vram1, index+1);	// G
		poke vram0, index+2, peek(vram1, index+2);	// R
	loop
loop
gsel 0:redraw 1

mrefでそれぞれのウィンドウやバッファのVRAMにアクセスできるようにして
あとは1ドットずつ読み込み（peek）と書き込み（poke）を同時にやってるだけです。

vwidth = ( (xsize*3) + 3 ) & 0xFFFFFFFC;
この計算はメモリー上での画像横幅を算出しています。

VRAMに関しての詳しい説明は検索すると色々出て来ると思うので
細かい解説は省略しようと思ったのですが
wikiの解説が比較的簡単で詳しく書いてあるのでリンクを貼っておきます。
https://wiki.hsp.moe/%E5%B0%8F%E3%83%AF%E3%82%B6%EF%BC%8FVRAM%E3%82%92%E7%9B%B4%E6%8E%A5%E6%93%8D%E4%BD%9C%E3%81%97%E3%81%A6%E3%81%BF%E3%82%8B.html

pokeとpeekを使えば良かったんですね。
画像の表示は早いのに、何故pgetとpsetでは遅いのか気になりました。
ありがとうございます。

なぜ1dot単位で処理をするのですか？
1dotにする利点などはありますか？

>中村実さん
ゆーさんが何を目的にやっているのかはわかりませんが
1ドット単位の処理は主に画像加工などで使えます。

・画像をセピア調やグレースケールにする色調補正系
・モザイク処理
・ぼかし、シャープ
・特定色の選択や書き換え
・画像の拡大、縮小、回転、ゆがみ加工
などなど

これらの内いくつかは標準命令を工夫するなどで可能ですが
標準命令とは違ったアルゴリズムで実行することで
精度が上がったりするという効果も期待できます。

このスレッドにあるソースがただの画像コピーのために利点が無さそうですが
独自の画像形式で保存・読込なんかも可能になりますし
なんらかのデータを画像形式に見せかけて保存するとか
ドット単位の処理をすることで色々と応用ができますよ。

なるほど、そのような使い方があるのですね。