文字列を暗号化して保存するモジュールを作ってみました。
これでメモ帳等に関連づけされてないような拡張子を使って保存すれば、
（気合いを入れて暗号を解読しようとする人が相手でもない限りは）
メモ帳等で中身を覗かれる心配はないと思います。
ただし、あくまでもxorを使った簡易的な処理なので、あまり強い暗号化ではありません。
これでは不足なようならもっと強い暗号化処理が必要になるかもしれません。
//・savetext p1,p2,p3
//文字列p2の内容をp1という名前のファイルに保存する。
//p3は暗号鍵を整数で指定する。省略可能で、省略時もしくは0を指定した場合は暗号化しない。
//（xorを使った簡易的な暗号化処理です。
// 暗号鍵には『0と1のビットがおよそ半々ぐらい存在してバラけている』値を推奨します）
//
//・loadtext p1,p2,p3
//p1という名前のテキストファイル、もしくはsavetextで暗号化して保存したテキストを変数p2に読み込む。
//暗号化したファイルを読み込む場合はp3に暗号鍵を整数で指定する。
//暗号化していないテキストの場合はp3を省略するか0を指定する。
#module
#define shift(%1) %1=(%1>>31)&0x1|(%1<<1)^0xFFFFFFFF //%1を左に1ビットローテートさせて全体を反転する
#define global savetext(%1,%2,%3=0) _savetext %1,%2,%3
#deffunc _savetext str fn1,str _text,int key1,local text,local buf1
k=key1 : f=k : text=_text
x=strlen(text) : y=(x+3)/4 : z=y*4
sdim buf1,z : memcpy buf1,text,x,0,0
repeat y
lpoke buf1,cnt*4,lpeek(buf1,cnt*4)^k
if f : shift k
loop
bsave fn1,buf1,x
return
#define global loadtext(%1,%2,%3=0) _loadtext %1,%2,%3
#deffunc _loadtext str fn2,var v,int key2,local buf2
exist fn2 : x=strsize : if x=-1 : return
k=key2 : f=k : y=(x+3)/4 : z=y*4
sdim buf2,z : bload fn2,buf2,x
repeat y
lpoke buf2,cnt*4,lpeek(buf2,cnt*4)^k
if f : shift k
loop
sdim v,x+1 : memcpy v,buf2,x,0,0
return
#global
//以下、使用例
test="あいうえお\nかきくけこ\nさしすせそ\nたちつてと\nなにぬねの\n123" //このテキストを保存したい
savetext "test.hog",test,0xDE39DFCA //テキストを暗号化して保存。第3パラは暗号鍵。
loadtext "test.hog",test2,0xDE39DFCA //暗号化したテキストを読み込む(元々の変数とは別の変数に)
mes test2 //読み込んだテキストを表示
新規拡張子ファイル 関連付け防止
