HSPTV!掲示板

最近ゲームとか、役に立たないものしか作ってないので、
タイピングゲームを作りたいと思ったのですが・・・
タイピング関係の命令を一度も扱ったことがありません！

タイピングソフトを作るにあたって知っておきたい・必要な
命令を教えてくれませんか？
（初心者級の知能を持ち合わせています。）

初心者級の知能？　こんな事ではまだまだ修行が足りない証拠だ。
HSP タイピング でググってみろ。こんな投稿をしたこと自体が恥ずかしくなるはずだ。
誰かに見つかる前にこっそり削除しておきなさい。

え？　恥ずかしくならない？　ああ、そう……

ググるの下手なんで(汗)
サンプル拾ってこようにも、実行ふぁいるくらいしか
みつからないもので・・・
一応再チャレンジしてみます。（検索を）

難しいです。（サンプル）
とりあえず、頑張ってonkey?など等の使い方を調べてみます。

他の処理と並行してキーの入力を調べるような命令が必要になると思う。
メインループをぐるぐる回しながら、その中でキーの入力を拾うような命令が。
onkey gosub や、onkey 0、onkey 1といった命令は必修科目になると思う。

問題を正確に混ぜる処理を書く必要があると思う。
rnd命令が使えるんだけど、ただrnd命令で問題を選んでしまうと、同じ問題を何度も出してしまう可能性があるので、
たとえば、0〜9の数字を1902484637 というようにきれいに順番を入れ替えるような処理を書く必要があると思う。

問題と答えを一組にして記憶させておくようにすると、楽だと思う。
たとえばだけど、sdim TANGO,255,2 として、TANGO(0)に問題、TANGO(1)に答えを記憶させる。とか。そんな工夫が。

サンプルの中にタイピングゲームがあった気がする。

タイピングソフトを作ったことはありませんが、
「peek関数」と「strmid関数」が役立つと思います

"し"という文字の入力を
"SI"、"SHI"、"CI"
のどれでも判定できるようにするなら、必須だと思います


あとは「strlen関数」が必要かもしれません

使い方はそれぞれヘルプ等で調べてみて下さい

てか初心者が作ろうとするなよ

HSPには標準でタイピングのサンプルが付いてきてますよ。

	;
	;	タイピングゲーム サンプル
	;
	title "タイピングゲーム"
	randomize
*start
	;	ゲーム開始
	score=0
*greset
	;	問題の準備
	cursor=0
	timer=250
	typemode=0
	m=rnd(3)
	if m=0 : mondai="HOTSOUPPROCESSOR":mondai2="ホットスーププロセッサ"
	if m=1 : mondai="HSPSCRIPTEDITOR":mondai2="HSPスクリプトエディタ"
	if m=2 : mondai="HSPTVDEASOBOU":mondai2="HSPTVで遊ぼう"
	onkey gosub *typein
*main
	;	ゲームメイン
	redraw 0
	color 192,192,192:boxf
	font msgothic,16
	color 0,0,0
	pos 80,20:mes "残り時間:"+timer
	pos 80,40:mes "スコア:"+score
	font msgothic,30,1
	color 0,120,160
	pos 170,198:mes mondai2
	pos 170,238:mes mondai
	pos 170,238:color 255,0,0:mes strmid(mondai,0,cursor)
	redraw 1
	await 50
	if typemode>0 : onkey 0 : goto *greset
	if timer<=0 : onkey 0 : goto *gameover
	timer=timer-1
	goto *main
*gameover
	onkey 0
	dialog "ゲームオーバー"
	end

*typein
	;	キーを押した時の処理
	a=peek(mondai,cursor)
	if a!=iparam : goto *typemiss
	len=strlen(mondai)
	cursor=cursor+1:if cursor<len : return
	goto *win
*typemiss
	;	ミスタッチをした時
	return
*win
	;	タイピング成功
	typemode=1
	score+=10
	return

返信遅れてすみません。
テスト明けでなまけていました。
yamaziさん＞
STGを作った上で、少しランクアップしてみようと思ったのですが、
結構ハードルたかかったみたいですね

TMKLさん＞
ありがとうございます。
peek,strmid関数ですね
checkさん、てれてれさん＞
サンプルありましたか、
ヘルプもちゃんと読んでみます。
Mさん＞
分かりやすく説明ありがとうございます。

僕のまだ知らない関数がたくさんでてきましたので、
まずはこれで慣れていきたいと思います。
みなさんありがとうございました。