> 大富豪 さん
関連した制作をしたことがありましたのでコメントさせて頂きます。
複数マウスの座標取得は Win32APIのRaw入力デバイス関数で実現できます。
手法としては、zakki さんの言っていることがすべてでして、
WM_INPUT メッセージにて取得できるマウスデバイスのハンドル値を
調べることで、どのマウスの入力データなのかを判断区別できます。
マウスの入力座標データは相対移動量となります。
マウスごとの絶対座標の取得については私も調査していましたが解決していません。。
Windows自体が接続されたマウスごとに絶対座標を個別管理しているのかも不明です。
以下サンプルでは、番号、ハンドル値、XY座標、ボタン情報を表示します。
XY座標は相対座標を加減算した値となっています。
ウィンドウがアクティブ時のみ、マウス入力処理を行なっています。
マウスカーソルと座標は連動していないので画面四隅で止まっても移動量は増減されます。
サンプルでは事前にマウス接続数を処理していませんので（Windowsドライバ系の処理となる）
新たに別なマウスの入力（ハンドル）があれば表示が追加されていきます。
この辺りが必要であれば、GENKI さんの URL添付している inoviaさんの SetupAPIの処理が
参考になるかも知れません。
#uselib "user32"
#func RegisterRawInputDevices "RegisterRawInputDevices" int,int,int
#func GetRawInputData "GetRawInputData" int,int,int,int,int
#define WM_INPUT $00FF
#define RID_INPUT $10000003
#define MAX_MOUSE 16
dim hMo,MAX_MOUSE
dim moX,MAX_MOUSE:dim moY,MAX_MOUSE:dim moB,MAX_MOUSE
oncmd gosub *on_wminput,WM_INPUT
dim RIDEV,3
RIDEV.0=$01+($02<<16)
RIDEV.1=0 //0=アクティブ時のみ/$100=すべて
RIDEV.2=hwnd
RegisterRawInputDevices varptr(RIDEV),1,12
if stat==0:dialog "RID Error":end
repeat
redraw 0:color 255,255,255:boxf
color:pos 0,0
repeat mxMo
mes strf("%2d)$%08X:(%5d,%5d):$%08X",cnt+1,hMo.cnt,moX.cnt,moY.cnt,moB.cnt)
loop
redraw 1:await 1000/30
loop:stop
*on_wminput
GetRawInputData lparam,RID_INPUT,0,varptr(sz),16
if sz{
dim RIDDT,(sz>>2)+1
GetRawInputData lparam,RID_INPUT,varptr(RIDDT),varptr(sz),16
if stat>0{
hRid=RIDDT.2:setd=0
repeat MAX_MOUSE
if hMo.cnt==hRid:setd=1
if hMo.cnt==0:hMo.cnt=hRid:setd=1:mxMo++
if setd:moX.cnt+=RIDDT.7:moY.cnt+=RIDDT.8:moB.cnt=RIDDT.5:break
loop
}}
return
複数のマウスの座標取得
